fpsとは

 今回のここでは、ファーストパーソン・シューティングゲーム(First Person Shooter)の略のことではありません。
fps(Frames Per Second)とは、フレームレート(単位時間あたり何度画面が更新されるかを表す指標)の単位のことをいいます。
たとえば1秒間に画面が30回書き直されていれば、30fpsと表記します。

通常、fps値が大きいほど滑らかに動いて見え、fps値が小さいほどカクカクに動いているように見えます。

fpsを指定するには?

 E3Dではfps値の上限を設定しないと、処理が軽いときは高速に表示し、処理が重くなると表示が 遅くなってしまい、ゲーム中の速度が速くなったり遅くなったり不安定になってしまいます。
また、ユーザーが使用するPCのスペックによってもスピードが変わってしまいます。
この問題の回避はいつもは、awaitを使用して安定化をやっていますよね。

 awaitでは指定したいフレームレートごとに待ち時間を計算する必要がありましたが、 E3Dでは速度の上限値をE3DWaitByFPS命令によって直接fps値で指定してやることが出来ます。

 E3DWaitByFPS命令による指定はfps値の上限を設定するだけなので、 遅いPCでFPS値が吊り上げられるわけではありません。
軽い場合は指定のfpsになるよう調整されますが、処理が重いときはfps値は指定値よりも 小さくなることがあります。

FPS値の表示を安定させる

 E3DWaitByFPS命令では実際のfps値を取得することが出来ます。
しかしfps値は値がふらついていて、そのまま表示しても小さい値が読み取れません。
このため、fps値による正確な処理速度の比較などが困難です。

 そこで今回は、fps値をある程度安定させて表示させてみることにします。
やり方は単純で、常に過去120回分(約2秒)のfps値の平均を表示させます。
【注意!】実際のfps値が安定するわけではありません。あくまで、表示を安定させて見やすくしただけのものです。

サンプル

ウィンドウのタイトルバーにフレームレートを表示しています。
フレームレート

;
;	FPSの安定表示化モジュール
;

#include "e3dhsp3.as"

;############################################################
#module
;E3DWaitByFPSの現在のFPSの安定表示化モジュール。
;不安定でみにくいFPSを見やすいように平均されたFPS値を取得できます。
;【注意】実際の動作でのFPS値が安定するわけではありません。

;初期化
#deffunc m_IntWaitByFPS int count
	;平均回数
	ddim tfps, count
	avg = count		;平均回数
	totalfps = 0.0	;平均回数の合計時間
	cfps = 0		;回数カウント用
	return

;E3DWaitByFPSを実行
#deffunc m_WaitByFPS int fps, var avgfps
	totalfps -= tfps.cfps
	E3DWaitByFPS fps, _tfps : await 0
	tfps.cfps = double(_tfps)
	totalfps += tfps.cfps
	avgfps = totalfps / avg
	if cfps<avg-1 : cfps++ : else : cfps = 0
	return

#global
m_IntWaitByFPS 120	;120回分の平均
;############################################################

	;/////////////////
	;
	;	初期化
	;
	wid = 0		;ウインドウID
	objid = -1	;オブジェクトID
	fullscreenflag = 0		;フルスクリーンフラグ
	bits = 16	;色数ビット数(fullscreenflag = 1 のときのみ有効)
	multisamplenum = 0		;アンチエイリアスのマルチサンプル数(0,2~16)
	;scid	スワップチェインID
	E3DInit wid, objid, fullscreenflag, bits, multisamplenum, scid
	dim keybuf, 256		;キー入力


	;/////////////////
	;
	; ライトの設定
	;
	E3DCreateLight lid1 ;光源を作成
	lightdirx1 = 1 ;平行光の向き
	lightdiry1 = -1
	lightdirz1 = 0
	lightr1 = 255	;平行光の色
	lightg1 = 255
	lightb1 = 255
	E3DSetDirectionalLight lid1, lightdirx1, lightdiry1, lightdirz1, lightr1, lightg1, lightb1 ;光源を平行光源に設定

	;/////////////////
	;
	;	カメラの初期化
	;
	camposx = 0 : camposy = 1000 : camposz = -4200
;	camposx = 0 : camposy = 0 : camposz = 4200	;デフォルト値
	E3DSetCameraPos camposx, camposy, camposz	;カメラ座標を設定
	targetx = 0		;注視点座標
	targety = 0
	targetz = 0
	upvecx = 0		;カメラの上方向のベクトル
	upvecy = 1
	upvecz = 0
	E3DSetCameraTarget targetx, targety, targetz, upvecx, upvecy, upvecz	;カメラの注視点を設定
	;プロジェクションの設定
	proj_near = 100.0 : proj_far = 50000.0 : proj_fov = 45.0
	E3DSetProjection proj_near, proj_far, proj_fov


	;/////////////////
	;
	;	地面の作成
	;
	sdim pathbuf, 2048, 4
	pathbuf.0 = dir_cur + "\\Media\\yama.bmp"	;地面の座標情報
	pathbuf.1 = dir_cur + "\\Media\\michi.bmp"	;地面の道の情報
	pathbuf.2 = dir_cur + "\\Media\\kawa.bmp"	;地面の川の情報
	pathbuf.3 = dir_cur + "\\Media\\bazou.bmp"	;地面、道、川の模様を決める、BMPファイル

	;地面作成用の値
	mapsize = 60000.0		;X,Z座標の最大値
	mapdiv = 60			;座標の分割数
	mapheight = 3000.0	;高さの最大値

	E3DLoadGroundBMP pathbuf.0, pathbuf.1, pathbuf.2, pathbuf.3, mapsize, mapsize, mapdiv, mapdiv, mapheight, hsid0
	posx0 = 0.0 : posy0 = 0.0 : posz0 = 0.0
	degx0 = 0.0 : degy0 = 0.0 : degz0 = 0.0
	E3DSetPos hsid0, posx0, posy0, posz0	;地面表示位置を設定
	E3DSetDir hsid0, degx0, degy0, degz0	;地面の向きを設定
	frameno0 = 0	;モーションは使用しない。


	;/////////////////
	;
	;	形状データのロード
	;
	sdim mediadir, 2048
	mediadir = dir_cur + "\\Media\\tako.sig"
	E3DSigLoad mediadir, hsid1
;	E3DSetPos hsid1, 13000, -1000, 16000
	E3DSetPosOnGroundPart hsid1, hsid0,, mapheight,, 13000, 16000
	E3DRotateY hsid1, 180
	frameno1 = 0	;モーションは使用しない。
	E3DSetBeforePos hsid1


;/////////////////
;
;	メインループ
;
*main
	E3DGetKeyboardState keybuf	;キー状態取得


	E3DBeginScene	;-----シーンスタート
		E3DChkInView scid, hsid0	;モデルが、視野内にあるか判定
		E3DChkInView scid, hsid1

		if keybuf.VK_ESCAPE = 1 : goto *bye ; [ESC]で終了
		gosub *MoveChara		;キャラクター移動

		gosub *ChkConf	;地面との当たり判定
		gosub *MoveCamera		;カメラ移動

		;不透明部分の描画をする
		E3DRender scid1, hsid0, 0, frameno0, 0	;バックバッファにレンダリングする。(地面描画)
		E3DRender scid1, hsid1, 0, frameno1, 0	;バックバッファにレンダリングする。(タコ描画)
		;半透明部分の描画をする
		E3DRender scid1, hsid1, 1, frameno1, 0, 0, 0, 1

	E3DEndScene			;-----シーン終了
	E3DPresent scid1	;バックバッファの内容を、プライマリバッファに転送。描画する。
	E3DSetBeforePos hsid1

	m_WaitByFPS 60, chkfps1 : await 0
	title ""+strf("%3.1f", chkfps1) + " FPS"

goto *main


;
;	終了処理
;
*bye
	E3DDestroyLight lid1	;ライトを破棄
	E3DBye
	end


;/////////////////
;
;	キャラクター移動
;
*MoveChara
	forwardstep = 100	;移動速度(前進)
	backstep = -forwardstep	;移動速度(後退)
	degstep = 5
	mdegstep = -degstep

	if keybuf.VK_UP    = 1 : E3DPosForward hsid1, forwardstep	;矢印上
	if keybuf.VK_DOWN  = 1 : E3DPosForward hsid1, backstep	;矢印下
	if keybuf.VK_LEFT  = 1 : E3DRotateY hsid1, mdegstep	;矢印左
	if keybuf.VK_RIGHT = 1 : E3DRotateY hsid1, degstep	;矢印右
	return


;/////////////////
;
;	カメラ移動(キャラクター追跡型)
;
*MoveCamera
	;キャラクターを後ろに2500移動して座標を取得。backpos
	E3DGetPos hsid1, saveposx1, saveposy1, saveposz1
	E3DPosForward hsid1, -2500
	E3DGetPos hsid1, backposx, backposy, backposz
	E3DSetPos hsid1, saveposx1, saveposy1, saveposz1
	;カメラをキャラクタ後方に設置
	E3DSetCameraPos backposx, backposy + 1500, backposz
	E3DSetCameraTarget saveposx1, saveposy1 + 800, saveposz1, 0, 1, 0
	return


;/////////////////
;
;	キャラクタの地面との当たり判定
;
*ChkConf
	mapminy = -100	;地面データのY座標の最小値。実際の最小値より、少し小さな値を入れる。
	E3DChkConfGround hsid1, hsid0, 1, mapheight, mapminy, result, adjustx, adjusty, adjustz, nx, ny, nz
	E3DSetPos hsid1, adjustx, adjusty, adjustz	;地面の上に移動
	return